/* LR, W, and LM TESTS FOR THE MEAN OF AN EXPONENTIAL DISTRIBUTION */

/* Initializations and Definitions */
Rtheta = 7.5;
xlength = 175;
loops = 1;
xtheta = seqa(3,0.1,xlength);
lnL = zeros(xlength,1);
dlnL = zeros(xlength,1);
ctheta = zeros(xlength,1);

/* Generate Data */
nobs = 100;
beta = 0.1;
alpha = 1;
x = beta*rndgam(nobs,1,alpha);

/* Unrestricted ML Estimate */
sumx = sumc(x);
URbeta = sumx/nobs;
URtheta = 1/URbeta;
print "Unrestricted Theta Hat = " URtheta;

/* Likelihood Ratio Test */
URlnLik = nobs*ln(URtheta) - URtheta*sumx;
RlnLik = nobs*ln(Rtheta) - Rtheta*sumx;
LR = -2*(RlnLik - URlnLik);
print "Unrestricted Likelihood = " URlnLik;
print "Restricted Likelihood = " RlnLik;
print "LR Statistic = " LR;
print;

/* Wald Test */
URInfo = nobs/(URtheta^2);
W = ((URtheta - Rtheta)^2)*URinfo;
print "Wald Statistic = " W;
print;

/* Lagrange Multiplier Test */
gr = nobs/Rtheta - sumx;
RInfo = nobs/(Rtheta^2);
LM = (gr^2)/Rinfo;
print "LM Statistic = " LM;
print;

/* Graph of Counterpart to Figure 4.8 */  
do while loops <= xlength;
 	theta = xtheta[loops,1];
	lnL[loops,1] = nobs*ln(theta) - theta*sumx - 100;
  	dlnL[loops,1] = nobs/theta - sumx;
	ctheta[loops,1] = theta - Rtheta;
	loops = loops + 1;
endo;

library pgraph;
graphset;
_pline = 1~6~0~0~100~0~1~5~4;
_pltype = {6 6 6};
_plegctl = {2 3 6 5};
_plegstr = "Log Likelihood\000d(ln L)/d(theta)\000c(theta)";
title("Counterpart to Figure 4.8 -- Exponential Distribution (n=100)"); 
xlabel("Theta");
data = lnL~dlnL~ctheta;
xy(xtheta,data);